I have a few equations which take the weekly HIGH, LOW and CLOSE as inputs and will give certain values. These values should be plotted on daily charts. Please help on how to go about it. Thanks.

Does this take care of the errors caused by holidays on certain weeks ?

Hi PT

Yes, my formula does take care of potential errors caused by holidays on certain weeks. It also takes care of missing days or data gaps for any other reason.

Weekly Camarilla levels can easily be calculated from the weekly prices, assuming that you have the formulas for these levels (the way you calculate Camarilla levels might be different from the way I do). Setting the Q variable default to 2 would hold the previous week’s levels until the first intraday bar of the new trading week begins to form. Outputs can easily be forced to plot values relating just to the previous week by wrapping each price definition in LastValue().

The formula for weekly Camarilla levels is shown below with all 8 levels restricted to plotting on 25 bars only. This limitation can be easily changed by adjusting the last definition of "Z". The indicator should plot on intraday charts as well as EOD charts, still returning weekly levels of course.

Daily levels could be based on my "Multi-Frame X OHLC" formula but I can’t show that here as it’s only available to MSTT subscribers or owners of the Multi-Frame Intraday kit. However, something quite simple (but adequate for the task) could be put together using DayOfWeek()<>Ref(DayOfWeek(),-1) as a start-of-new-week trigger for sampling daily prices.

Roy

{Multi-Frame D Camarilla Levels}

{Requires Equis Forum DLL}

{Roy Larsen, 2009, 8/10/09}

{User settings}

N:=Input("Multi-Frame D Camarilla Levels",0,0,0);

J:=Input("Months per Frame, 0=Weekly",0,12,0);

J:=If(J<5 OR Mod(J,3)=0 AND (J<>9),Int(J),-1);

Q:=Input("Mode, 0=Static 1=Dynamic 2=Delayed",0,2,2);

{Update on last bar, new bar or new frame}

{Timing signals}

{Day counter courtesy metastock@wabbit.com.au}

M:=Month();A:=Int((14-M)/12);D:=DayOfMonth();

Y:=Year();X:=Y+4800-A;B:=M+(12*A)-3;Z:=Cum(1);

M:=If(J=0,D+Int((2+153*B)/5)+(365*X)+Int(X/4)-

Int(X/100)+Int(X/400)-32045,{day counter}

(Y-ValueWhen(1,Z=1,Y))*12+M){month counter};

I:=If(J=0,Int(M/7),Int((M-1)/Max(1,J)));

I:=I<>ValueWhen(2,1,I);

G:=LastValue(J<0 OR Lowest(Sum(I>0,5))=5);

I:=ExtFml("Forum.Sum",I,1);M:=G OR I;

F:=G OR (M=0)*ExtFml("Forum.Sum",Ref(I,1),1);

A:=LastValue(Z-1)=Z;B:=LastValue(Z)=Z;

F:=F+B*(Q=0)*(J=0)*(DayOfWeek()=5);

J:=If(F,1,(Alert(F,2)=0)*M*2*(Z>1));

J:=If(A+LastValue(J)>2 OR B+(Q=1)=2,1,J);

J:=If(G,1,If(Q=2,M*2,J));

{Frame prices}

Om:=ValueWhen(1,M OR Z=1,O);

Om:=ValueWhen(1,J,If(J=1,Om,ValueWhen(2-G,1,Om)));

Hm:=HighestSince(1,M OR Z=1,H);

Hm:=ValueWhen(1,J,If(J=1,Hm,ValueWhen(2-G,1,Hm)));

Lm:=LowestSince(1,M OR Z=1,L);

Lm:=ValueWhen(1,J,If(J=1,Lm,ValueWhen(2-G,1,Lm)));

K:=ValueWhen(1,J,If(J=1,C,ValueWhen(2-G,1,C)));

Z:=LastValue(Z)-25=Z;

{Camarilla levels}

ValueWhen(1,Z,LastValue(K+(Hm-Lm)*1.1/2)); {R4}

ValueWhen(1,Z,LastValue(K+(Hm-Lm)*1.1/4)); {R3}

ValueWhen(1,Z,LastValue(K+(Hm-Lm)*1.1/6)); {R2}

ValueWhen(1,Z,LastValue(K+(Hm-Lm)*1.1/12));{R1}

ValueWhen(1,Z,LastValue(K-(Hm-Lm)*1.1/12));{S1}

ValueWhen(1,Z,LastValue(K-(Hm-Lm)*1.1/6)); {S2}

ValueWhen(1,Z,LastValue(K-(Hm-Lm)*1.1/4)); {S3}

ValueWhen(1,Z,LastValue(K-(Hm-Lm)*1.1/2)); {S4}

Save the Forum DLL to the "External Function DLLs" folder (under the "MetaStock" folder) and then restart MetaStock.

Roy

Hi PT

1. Apart from H5 and L5 I think my definitions agree with yours. A MetaStock-syntax version of your code is shown at the bottom of this post.

2. Once added to the formula already posted you’ll be able to plot either weekly or monthly Camarilla levels merely by changing the "Months per Frame" default value to 1 (month). To plot both weekly and monthly values at the same time make a duplicate copy of my indicator, then change the name and the default input value of the copy. I’ll look at setting up a daily version and the additional outputs later on today.

3. I’m not aware of an expert or exploration for a Camarilla levels based system. My understanding is that such a system would be discretionary and so any system would vary from one individual to another. Explorations and experts are not that difficult to build but to source various levels from my indicator with FmlVar() functions the various levels would need to be assigned names (as below for example). The merging of daily, weekly and monthly indicators is not really practical as Metastock does not permit 30 named outputs (10 per each timeframe). Leaving outputs unnamed is fine when an indicator is used for display purposes only, but it’s useless if the outputs have to be available to other formulas.

Roy

H5:=(H/L)*C;

H4:=C+1.1*(H-L)/2;

H3:=C+1.1*(H-L)/4;

H2:=C+1.1*(H-L)/6;

H1:=C+1.1*(H-L)/12;

L1:=C-1.1*(H-L)/12;

L2:=C-1.1*(H-L)/6;

L3:=C-1.1*(H-L)/4;

L4:=C-1.1*(H-L)/2;

L5:=C-(H5-C);

H5; H4; H3; H2; H1; L1; L2; L3; L4; L5;

Is this possible ? What I am looking for is automation of the stock picking process. Please allow me to discuss in detail the aspects I am looking for. 1. Camarilla levels shall be calculated as per the following equations : H5 = (H/L)*C H4 = [1.1*(H-L)/2]+C H3 = [1.1*(H-L)/4]+C H2 = [1.1*(H-L)/6]+C H1 = [1.1*(H-L)/12]+C L1 = C-[1.1*(H-L)/12] L2 = C-[1.1*(H-L)/6] L3 = C-[1.1*(H-L)/4] L4 = C-[1.1*(H-L)/2] L5 = C-(H5-C) 2.These levels must be used to develop a Custom Indicator, a Custom Exploration and a Custom Expert Advisor. 3.All of the above must take care of trading holidays even those which fall within the week. 4.Custom Indicator : An integrated indicator which will display the weekly and daily Camarilla levels when plotted on any chart irrespective of whether it is an RealTime intraday chart, a daily chart or a weekly chart with easily recognisable colour coding. Also a seperate indicator for monthly Camarilla levels. 5.Custom Exploration : Three seperate explorations (daily, weekly and monthly) to find out which stocks are trading near any of the Camarila levels. 6.Custom Expert Advisor : An advisor which when attached to a chart, whether its an RT intraday chart, a weekly chart or a monthly chart, alerts with a visual and audio alert when the stock trades near any of the Daily, Weekly or Monthly Camarilla levels. 7.Changes necessary in the coding if the numbers (2,4,6,12) in the equations are to me modified. 8.System tester. 9.Passowrd protection (of course should be know to me) for all of the above.