logo
Welcome Guest! To enable all features please Registers on the forum or Register.

Notification

Icon
Error
2 Pages12>
I need the expert(s) - I need the expert(s)
Options
Go to last post Go to first unread
Previous Topic Next Topic
eddie.m  
#1 Posted : Monday, January 14, 2013 5:55:44 AM(UTC)
eddie.m

Rank: Advanced Member

Groups: Registered, Registered Users
Joined: 1/20/2012(UTC)
Posts: 152

Was thanked: 1 time(s) in 1 post(s)

Hello,

I am trying to color the six MACD Histogram phases:

  1. MACD < 0 and falling = red
  2. MACD < 0 and rising = dark green
  3. MACD > 0 and rising = light green
  4. MACD > 0 and falling = brown

I did all this nicely, using the barssince function. [:D] But I cannot color the 5th and 6th phases, no matter what I did. [:'(] [:$]

#5 is when after Dark Green, prices instead of going up go down.

#6 is when after Brown, prices instead of going down go up.

I managed to do something, but then #5 and #6 are replacing the Dark Green and Red areas COMPLETELY. [:@]

I wish I could upload a picture in here to show what I mean ...

Your assistance is greatly appreciated.
Back to top

Wanna join the discussion?! Login to your Discussions forum accountor Register a new forum account.
Back to top  
wabbit  
#2 Posted : Monday, January 14, 2013 6:08:36 AM(UTC)
wabbit

Rank: Advanced Member

Groups: Registered, Registered Users, Subscribers, Unverified Users
Joined: 10/28/2004(UTC)
Posts: 3,111
Location: Perth, Western Australia

Was thanked: 16 time(s) in 16 post(s)
There are heaps of posts on how to post images.... Also, post your code. wabbit [:D]
Back to top
eddie.m  
#3 Posted : Monday, January 14, 2013 6:23:54 AM(UTC)
eddie.m

Rank: Advanced Member

Groups: Registered, Registered Users
Joined: 1/20/2012(UTC)
Posts: 152

Was thanked: 1 time(s) in 1 post(s)

Hi Wab,

MACD Histogram formula

MACD()-Mov(MACD(),9,E)
Back to top
wabbit  
#4 Posted : Monday, January 14, 2013 6:28:54 AM(UTC)
wabbit

Rank: Advanced Member

Groups: Registered, Registered Users, Subscribers, Unverified Users
Joined: 10/28/2004(UTC)
Posts: 3,111
Location: Perth, Western Australia

Was thanked: 16 time(s) in 16 post(s)
What about the six conditions code attempt? wabbit [:D]
Back to top
eddie.m  
#5 Posted : Monday, January 14, 2013 10:00:31 AM(UTC)
eddie.m

Rank: Advanced Member

Groups: Registered, Registered Users
Joined: 1/20/2012(UTC)
Posts: 152

Was thanked: 1 time(s) in 1 post(s)

Hi there,

{red}
If(MACD()-Mov(MACD(),9,E)<0 AND MACD()-Mov(MACD(),9,E)<Ref(MACD()-Mov(MACD(),9,E),-1) AND BarsSince(MACD()-Mov(MACD(),9,E)<0 AND MACD()-Mov(MACD(),9,E)<Ref(MACD()-Mov(MACD(),9,E),-1)) < BarsSince(MACD()-Mov(MACD(),9,E)>0 AND MACD()-Mov(MACD(),9,E)<Ref(MACD()-Mov(MACD(),9,E),-1)),MACD()-Mov(MACD(),9,E),0)


{dark green}
If(MACD()-Mov(MACD(),9,E)<0 AND MACD()-Mov(MACD(),9,E)>Ref(MACD()-Mov(MACD(),9,E),-1) AND BarsSince(MACD()-Mov(MACD(),9,E)<0 AND MACD()-Mov(MACD(),9,E)>Ref(MACD()-Mov(MACD(),9,E),-1)) < BarsSince(MACD()-Mov(MACD(),9,E)<0 AND MACD()-Mov(MACD(),9,E)<Ref(MACD()-Mov(MACD(),9,E),-1)),MACD()-Mov(MACD(),9,E),0)

{light green}
If(MACD()-Mov(MACD(),9,E)>0 AND MACD()-Mov(MACD(),9,E)>Ref(MACD()-Mov(MACD(),9,E),-1) AND BarsSince(MACD()-Mov(MACD(),9,E)>0 AND MACD()-Mov(MACD(),9,E)>Ref(MACD()-Mov(MACD(),9,E),-1)) < BarsSince(MACD()-Mov(MACD(),9,E)<0 AND MACD()-Mov(MACD(),9,E)>Ref(MACD()-Mov(MACD(),9,E),-1)),MACD()-Mov(MACD(),9,E),0)

{brown}
If(MACD()-Mov(MACD(),9,E)>0 AND MACD()-Mov(MACD(),9,E)<Ref(MACD()-Mov(MACD(),9,E),-1) AND BarsSince(MACD()-Mov(MACD(),9,E)>0 AND MACD()-Mov(MACD(),9,E)<Ref(MACD()-Mov(MACD(),9,E),-1)) < BarsSince(MACD()-Mov(MACD(),9,E)>0 AND MACD()-Mov(MACD(),9,E)>Ref(MACD()-Mov(MACD(),9,E),-1)),MACD()-Mov(MACD(),9,E),0)

{blue above 0 - not working}
If(MACD()-Mov(MACD(),9,E)>0 AND MACD()-Mov(MACD(),9,E)<Ref(MACD()-Mov(MACD(),9,E),-1) AND BarsSince(MACD()-Mov(MACD(),9,E)>0 AND MACD()-Mov(MACD(),9,E)<Ref(MACD()-Mov(MACD(),9,E),-1)) < BarsSince(MACD()-Mov(MACD(),9,E)>0 AND MACD()-Mov(MACD(),9,E)<Ref(MACD()-Mov(MACD(),9,E),-1)),MACD()-Mov(MACD(),9,E),0)

{blue below 0 - not working)
If(MACD()-Mov(MACD(),9,E)<0 AND MACD()-Mov(MACD(),9,E)<Ref(MACD()-Mov(MACD(),9,E),-1) AND BarsSince(MACD()-Mov(MACD(),9,E)<0 AND MACD()-Mov(MACD(),9,E)<Ref(MACD()-Mov(MACD(),9,E),-1)) < BarsSince(MACD()-Mov(MACD(),9,E)<0 AND MACD()-Mov(MACD(),9,E)>Ref(MACD()-Mov(MACD(),9,E),-1)),MACD()-Mov(MACD(),9,E),0)

What I need is to have the MACD Histogram bars colored in Blue after prices rise after a Brown area, and colored also in Blue after prices drop after a Dark Green area.
Back to top
haddison  
#6 Posted : Monday, January 14, 2013 12:21:15 PM(UTC)
haddison

Rank: Advanced Member

Groups: Registered, Registered Users, Subscribers
Joined: 3/6/2010(UTC)
Posts: 113
Location: London
It would be better if you replaced MACD()-Mov(MACD(),9,E) with a variable - then the code would be much easier to read and understand. E.g.

MACDDiff:=MACD()-Mov(MACD(),9,E);
Back to top
wabbit  
#7 Posted : Monday, January 14, 2013 4:53:24 PM(UTC)
wabbit

Rank: Advanced Member

Groups: Registered, Registered Users, Subscribers, Unverified Users
Joined: 10/28/2004(UTC)
Posts: 3,111
Location: Perth, Western Australia

Was thanked: 16 time(s) in 16 post(s)
As Haddison suggested, simply replacing the main computation with a variable not only makes the code easier to read and maintain, it also speeds up processing as MS doesn't have to perform the same computations over and over:

Code:

MACDH:=MACD()-Mov(MACD(),9,E);

{red}
If(MACDH<0 AND MACDH<Ref(MACDH,-1) AND BarsSince(MACDH<0 AND MACDH<Ref(MACDH,-1)) < BarsSince(MACDH>0 AND MACDH<Ref(MACDH,-1)),MACDH,0)


{dark green}
If(MACDH<0 AND MACDH>Ref(MACDH,-1) AND BarsSince(MACDH<0 AND MACDH>Ref(MACDH,-1)) < BarsSince(MACDH<0 AND MACDH<Ref(MACDH,-1)),MACDH,0)

{light green}
If(MACDH>0 AND MACDH>Ref(MACDH,-1) AND BarsSince(MACDH>0 AND MACDH>Ref(MACDH,-1)) < BarsSince(MACDH<0 AND MACDH>Ref(MACDH,-1)),MACDH,0)

{brown}
If(MACDH>0 AND MACDH<Ref(MACDH,-1) AND BarsSince(MACDH>0 AND MACDH<Ref(MACDH,-1)) < BarsSince(MACDH>0 AND MACDH>Ref(MACDH,-1)),MACDH,0)

{blue above 0 - not working}
If(MACDH>0 AND MACDH<Ref(MACDH,-1) AND BarsSince(MACDH>0 AND MACDH<Ref(MACDH,-1)) < BarsSince(MACDH>0 AND MACDH<Ref(MACDH,-1)),MACDH,0)

{blue below 0 - not working)
If(MACDH<0 AND MACDH<Ref(MACDH,-1) AND BarsSince(MACDH<0 AND MACDH<Ref(MACDH,-1)) < BarsSince(MACDH<0 AND MACDH>Ref(MACDH,-1)),MACDH,0)


Now that we can see a little more clearly what is going on, we can start to question the BarsSince() functionality and decide it's redundant. So working only on the first four colou conditions for now, your code can be simplified into:

Code:

MACDH:=MACD()-Mov(MACD(),9,E);

{red}
red:=MACDH * (MACDH<0 AND MACDH<Ref(MACDH,-1));

{dark green}
dkGreen:=MACDH * (MACDH<0 AND MACDH>Ref(MACDH,-1));

{light green}
ltGreen:=MACDH * (MACDH>0 AND MACDH>Ref(MACDH,-1));

{brown}
brown:=MACDH * (MACDH>0 AND MACDH<Ref(MACDH,-1));

{plot}
red;
dkGreen;
ltGreen;
brown;


eddie.m wrote:
What I need is to have the MACD Histogram bars colored in Blue after prices rise after a Brown area, and colored also in Blue after prices drop after a Dark Green area.


In the last two conditions you posted, you have never referred to prices, so I am not at all surprised the conditions as coded didn't return what you expected in the text of your first post of this thread.

I'm not entirely sure of the definitions here, particularly your use of the word "after" which means some sort succession (?) but here's another interpretation:

Code:

MACDH:=MACD()-Mov(MACD(),9,E);

{red}
red:=MACDH * (MACDH<0 AND MACDH<Ref(MACDH,-1));

{dark green}
dkGreen:=MACDH * (MACDH<0 AND MACDH>Ref(MACDH,-1));

{light green}
ltGreen:=MACDH * (MACDH>0 AND MACDH>Ref(MACDH,-1));

{brown}
brown:=MACDH * (MACDH>0 AND MACDH<Ref(MACDH,-1));

upBlue:=MACDH * (brown AND C>Ref(C,-1));

dnBlue:=MACDH * (dkGreen AND C<Ref(C,-1));

{plot}
red;
dkGreen;
ltGreen;
brown;
upBlue;
dnBlue;


????????


wabbit [:D]


[edited : forgot to multiply the Boolean by the MACDH in the last two conditions]
Back to top
eddie.m  
#8 Posted : Monday, January 14, 2013 6:37:54 PM(UTC)
eddie.m

Rank: Advanced Member

Groups: Registered, Registered Users
Joined: 1/20/2012(UTC)
Posts: 152

Was thanked: 1 time(s) in 1 post(s)

Hi Hadison & Wabbit, [:D]

Thank you for your replies and codes.

Please look at MACD Histogram plotted as histogram attentively.

1. MACD goes below the 0 centerline. That’s “WINTER”, in red.

2. MACD forms a bottom and turns up. Two things happen:

a. MACD goes straight to 0 line. That’s “SPRING”, in dark green.

b. Or MACD going up begins to fall for a little while (touching the previous bottom or not is unimportant). All this before MACD reaches the 0 centerline. That’s “COLD SPELL IN SPRING”, in blue.

This is where the code must be different than in Winter, where MACD under the 0 line also falls.

3. MACD crosses above the 0 line and rises. That’s “SUMMER”, in light green.

4. MACD forms a top and reverses going down. Two things happen:

a. MACD goes straight down to the 0 line. That’s “AUTUMN” , in brown.

b. Or, falling MACD stops and goes up for a while (exceeding or not the previous top is unimportant). That’s ‘INDIAN SUMMER”, in blue too.

This again is where the code must be different than in Summer where MACD also rises above the 0 line.

As you see, I was able to color the four main phases already, but I could not do it for 2b and 4b above.

You the experts have knowledge and expertise which the rest of mortals do not have so I rely on you.

In my opinion, no reference to prices must be made in any code. The code should reflect only and only the six distinct MACD phases and be calculated only and only on MACD Histogram.

Your lines of code please. [:D]
Back to top
wabbit  
#9 Posted : Monday, January 14, 2013 6:56:16 PM(UTC)
wabbit

Rank: Advanced Member

Groups: Registered, Registered Users, Subscribers, Unverified Users
Joined: 10/28/2004(UTC)
Posts: 3,111
Location: Perth, Western Australia

Was thanked: 16 time(s) in 16 post(s)
You're confusing the issue by referring to the value of the MACD histogram as "price" -- it isn't

I think I get what you're looking for, so try this on for size:

Code:

MACDH:=MACD()-Mov(MACD(),9,E);

red:=MACDH * (MACDH<0 AND MACDH<Ref(MACDH,-1));
dkGreen:=MACDH * (MACDH<0 AND MACDH>Ref(MACDH,-1));
ltGreen:=MACDH * (MACDH>0 AND MACDH>Ref(MACDH,-1));
brown:=MACDH * (MACDH>0 AND MACDH<Ref(MACDH,-1));

upBlue:=MACDH * (ltGreen AND ltGreen<HighestSince(1,MACDH<0,MACDH));
dnBlue:=MACDH * (red AND red>LowestSince(1,MACDH>0,MACDH));

{plot}
red;
dkGreen;
ltGreen;
brown;
upBlue;
dnBlue;




wabbit [:D]

wabbit attached the following image(s):
macdh.png
Back to top
eddie.m  
#10 Posted : Monday, January 14, 2013 7:05:37 PM(UTC)
eddie.m

Rank: Advanced Member

Groups: Registered, Registered Users
Joined: 1/20/2012(UTC)
Posts: 152

Was thanked: 1 time(s) in 1 post(s)

Hello Wabbit,

Thank you.

While you were typing the reply, I was already correcting my post.[:D]

I tried your former code but it is not what I needed. Increase the length of MACDH from 9 to 200.

There should be only one red area, and only one light green area.

After brown area, if MACDH rises, there should be blue MACDH. After dark green area, if MACD drops, there should be blue MACDH too.

I am about to try your second formula NOW.
Back to top
eddie.m  
#11 Posted : Monday, January 14, 2013 7:20:19 PM(UTC)
eddie.m

Rank: Advanced Member

Groups: Registered, Registered Users
Joined: 1/20/2012(UTC)
Posts: 152

Was thanked: 1 time(s) in 1 post(s)

Hello Wabbit,

You got it, and you almost made it well.

Look at the chart you posted. The first light green, OK.

The two blue histogram vertical lines must continue to be blue over the next three lines.

The single red line pointing down to Bank of America should also be blue.

All the blue lines on the right are OK.

To make it easy for you, please increase the length of MACDH from 9 to 200 and you will get a good display.

THUMBS UP.

Back to top
eddie.m  
#12 Posted : Monday, January 14, 2013 7:20:36 PM(UTC)
eddie.m

Rank: Advanced Member

Groups: Registered, Registered Users
Joined: 1/20/2012(UTC)
Posts: 152

Was thanked: 1 time(s) in 1 post(s)

Hello Wabbit,

You got it, and you almost made it well.

Look at the chart you posted. The first light green, OK.

The two blue histogram vertical lines must continue to be blue over the next three light green lines.

The single red line pointing down to Bank of America should also be blue.

All the blue lines on the right are OK.

To make it easy for you, please increase the length of MACDH from 9 to 200 and you will get a good display.

THUMBS UP.

Back to top
wabbit  
#13 Posted : Monday, January 14, 2013 7:28:44 PM(UTC)
wabbit

Rank: Advanced Member

Groups: Registered, Registered Users, Subscribers, Unverified Users
Joined: 10/28/2004(UTC)
Posts: 3,111
Location: Perth, Western Australia

Was thanked: 16 time(s) in 16 post(s)
OK... my last try, you've got plenty enough from here to make some more attempts on your own....

Code:

MACDH:=MACD()-Mov(MACD(),200,E);

red:=MACDH * (MACDH<0 AND MACDH<Ref(MACDH,-1));
dkGreen:=MACDH * (MACDH<0 AND MACDH>Ref(MACDH,-1));
ltGreen:=MACDH * (MACDH>0 AND MACDH>Ref(MACDH,-1));
brown:=MACDH * (MACDH>0 AND MACDH<Ref(MACDH,-1));

upBlue:=MACDH * (ltGreen AND BarsSince(brown)<BarsSince(MACDH<0));
dnBlue:=MACDH * (red AND BarsSince(dkGreen)<BarsSince(MACDH>0));

{plot}
red;
dkGreen;
ltGreen;
brown;
upBlue;
dnBlue;



wabbit [:D]

P.S. Please post your final working code.

wabbit attached the following image(s):
macdh.png
Back to top
haddison  
#14 Posted : Monday, January 14, 2013 7:29:23 PM(UTC)
haddison

Rank: Advanced Member

Groups: Registered, Registered Users, Subscribers
Joined: 3/6/2010(UTC)
Posts: 113
Location: London
You might want to use Input("Text",Min,Max,Default) so that you can change the length from the Indicator window.

Periods:=Input("MACDLength",2,1000,200);
MACDH:=MACD()-Mov(MACD(),Periods,E);

Edit: Sorry Wabbit this was aimed at eddie - I know you already know this!
Back to top
eddie.m  
#15 Posted : Monday, January 14, 2013 7:31:46 PM(UTC)
eddie.m

Rank: Advanced Member

Groups: Registered, Registered Users
Joined: 1/20/2012(UTC)
Posts: 152

Was thanked: 1 time(s) in 1 post(s)

Idea to stress:

Within unspecified time segments, there should be only one red area, and only one light green area on any chart.

Inside brown area, if MACDH rises, there should be only blue MACDH lines for the duration of the rise. Inside dark green area, if MACDH drops, there should be only blue MACDH too for the duration of the drop. [:D]

Why blue in both situations? To reduce the number of colors (my personal preference).

You will discover an order you will perhaps grow to appreciate. [ip]
Back to top
eddie.m  
#16 Posted : Monday, January 14, 2013 7:37:30 PM(UTC)
eddie.m

Rank: Advanced Member

Groups: Registered, Registered Users
Joined: 1/20/2012(UTC)
Posts: 152

Was thanked: 1 time(s) in 1 post(s)
haddison wrote:
You might want to use Input("Text",Min,Max,Default) so that you can change the length from the Indicator window.

Periods:=Input("MACDLength",2,1000,200);
MACDH:=MACD()-Mov(MACD(),Periods,E);

Edit: Sorry Wabbit this was aimed at eddie - I know you already know this!

Hello Haddison,

Thank you. I used to use the Input function in the past, but now I want to keep things simple, and not keep on playing with this and that. But it's getting difficult to keep things simple, eeh?[;)]

I wish I knew how to program the way WABBIT does, but hey, ... [sn]
Back to top
eddie.m  
#17 Posted : Monday, January 14, 2013 8:02:17 PM(UTC)
eddie.m

Rank: Advanced Member

Groups: Registered, Registered Users
Joined: 1/20/2012(UTC)
Posts: 152

Was thanked: 1 time(s) in 1 post(s)

wabbit wrote:
OK... my last try, you've got plenty enough from here to make some more attempts on your own....

Code:

MACDH:=MACD()-Mov(MACD(),200,E);

red:=MACDH * (MACDH<0 AND MACDH<Ref(MACDH,-1));
dkGreen:=MACDH * (MACDH<0 AND MACDH>Ref(MACDH,-1));
ltGreen:=MACDH * (MACDH>0 AND MACDH>Ref(MACDH,-1));
brown:=MACDH * (MACDH>0 AND MACDH<Ref(MACDH,-1));

upBlue:=MACDH * (ltGreen AND BarsSince(brown)<BarsSince(MACDH<0));
dnBlue:=MACDH * (red AND BarsSince(dkGreen)<BarsSince(MACDH>0));

{plot}
red;
dkGreen;
ltGreen;
brown;
upBlue;
dnBlue;



wabbit [:D]

P.S. Please post your final working code.

Hi Wabbit,

The MACDH on your chart is beautiful.

This is it! [:O][:)][:D]

No matter what I do here, I won't be able to go your distance Wab. [A]

I already tried your formula on one stock at my end, and it looks like in my dream ...

I shall leave the thread open, not resolved for two more days, to see if something new comes up.

Thank you.
Back to top
wabbit  
#18 Posted : Monday, January 14, 2013 8:14:11 PM(UTC)
wabbit

Rank: Advanced Member

Groups: Registered, Registered Users, Subscribers, Unverified Users
Joined: 10/28/2004(UTC)
Posts: 3,111
Location: Perth, Western Australia

Was thanked: 16 time(s) in 16 post(s)
For a final parting shot -- you may encounter an issue with the above logic as we only trap the conditions "<" and ">" for the MACDH and its one-period change, but never the "=" conditions....

I'll leave that up you to decide if it's important, and if it is, how you might employ ValueWhen() to remedy the situation without generating four more variables.... a hint can be found at http://forum.equis.com/forums/permalink/17296/17331/ShowThread.aspx#17331
Back to top
eddie.m  
#19 Posted : Tuesday, January 15, 2013 10:26:04 AM(UTC)
eddie.m

Rank: Advanced Member

Groups: Registered, Registered Users
Joined: 1/20/2012(UTC)
Posts: 152

Was thanked: 1 time(s) in 1 post(s)

wabbit wrote:
For a final parting shot -- you may encounter an issue with the above logic as we only trap the conditions "<" and ">" for the MACDH and its one-period change, but never the "=" conditions....

wabbit [:D]

Hello Wabbit, [:D]

Thank you for your thoughts. It's hard to believe MACDHs could be equal.

I made an Indicator MACD()-Mov(MACD(),9,E)=Ref(MACD()-Mov(MACD(),9,E),-1) and also MACD()-Mov(MACD(),200,E)=Ref(MACD()-Mov(MACD(),200,E),-1) and I found no equality whatsoever. Zero. [:O]
Increasing the length of periods obviously increases the MACDH values but it also seems to reduce their difference during trends. However the exact differences are not important to me.
At tops and bottoms, MACDHs can never be equal. Maybe their differences are greater than during trends. These are MARKET TRUTHS.

On another thought, I am trying your last formula and began noticing something strange: what looked perfect last night seems different today. [:@]
I am checking what it is and I shall return to this thread in 2-3 days.
Back to top
eddie.m  
#20 Posted : Tuesday, January 15, 2013 8:26:16 PM(UTC)
eddie.m

Rank: Advanced Member

Groups: Registered, Registered Users
Joined: 1/20/2012(UTC)
Posts: 152

Was thanked: 1 time(s) in 1 post(s)

OK, this is it.

Six-in-one standalone Indicator:

Code:

Periods:=Input("MACD Length",2,1000,252);
MACDH:=MACD()-Mov(MACD(),Periods,S);
winter:=MACDH * (MACDH<0 AND MACDH<Ref(MACDH,-1));
spring:=MACDH * (MACDH<0 AND MACDH>Ref(MACDH,-1));
smmer:=MACDH * (MACDH>0 AND MACDH>Ref(MACDH,-1));
autumn:=MACDH * (MACDH>0 AND MACDH<Ref(MACDH,-1));
indiansmmer:=MACDH * (smmer AND BarsSince(autumn)<BarsSince(MACDH<0));
csinspring:=MACDH * (winter AND BarsSince(spring)<BarsSince(MACDH>0));
{plot} {typos are on purpose to avoid Sum() and 'col'umn functions}
winter; {red}
spring; {dark green}
smmer; {light green}
autumn; {brown}
indiansmmer; {blue}
csinspring; {blue}
Feel free to choose your own colors.
The above formula cannot be referenced in Expert Advisors, Enhanced System Tester and Explorations because of the presence of the semi-colons. One semi-colon is enough to block references.

To create six separate Indicators that may be referenced to, create six new Indicators one by one following this rule: replace every MACDH in the formula above with MACD()-Mov(MACD(),9,E).

Example:
{WINTER, red}
If(MACD()-Mov(MACD(),252,E)*(MACD()-Mov(MACD(),252,E)<0 AND MACD()-Mov(MACD(),252,E))<Ref(MACD()-Mov(MACD(),252,E),-1),MACD()-Mov(MACD(),252,E),0)

Feel free to choose your own periods. The default one is: 9.

For Indian Summer and Cold Spell In Spring, replace both MACDH with its formula and the season names (smmer, autumn, winter, spring) with their respective formulas.

Indicator "seasons" have been described by Dr. Alexander Elder in his 'Trading For A Living' book in 1993. Whether he invented MACDH or Gerald Appel (the father of MACD in 1979), I do not know. The concept is very simple, easy to grasp if you just look at MACD Histogram. Season order would be easy to monitor if it were not for Indian Summers and Cold Spells In Spring to occur randomly.

Thank you Haddison for participating and many thanks to Wabbit for doing justice to a useful, and now good-looking, Indicator.
Back to top
Users browsing this topic
Guest (Hidden)
2 Pages12>
Forum Jump  
You cannot post new topics in this forum.
You cannot reply to topics in this forum.
You cannot delete your posts in this forum.
You cannot edit your posts in this forum.
You cannot create polls in this forum.
You cannot vote in polls in this forum.

Powered by YAF.NET | YAF.NET © 2003-2024, Yet Another Forum.NET