One thing at a time...

If you want to add the Rate-of-Change together for different periods -- a week, 3 weeks and 5 weeks -- plot this:

ROC(C,5,%)+ROC(C,15,%)+ROC(C,25,%);


If you want to SUM() them, it will take the result for "x" number of days, and add them (not sure why you'd want this, though it might give an indication of Trend):

x:=10;
MyROC:=ROC(C,5,%)+ROC(C,15,%)+ROC(C,25,%);
Sum(MyRoc,x);


Hope that clarifies things. As a further example, if you wanted an average of the three ROC()'s, you would do it manually, rather than use MOV():

MyROC:=ROC(C,5,%)+ROC(C,15,%)+ROC(C,25,%);
MyROC/3;


MSFL (MetaStock Formula Language) isn't QUITE like Excel...but it can be helpful to think of MSFL "worded" functions as automatically stretching back through the data, as though you were working at the bottom of a column in a spreadsheet, while the simpler functions like "+", ">", etc. operate on individual variables, like "MyROC" in the example above.

Also, download and review the Formula Primer, if you haven't already.

Well, it seemed to do better on the COMP at -4%, and on the NDX at +4%, from what I could tell. Did he say anything about stops, smoothing, etc?

MyROC:=ROC(C,5,%)+ROC(C,15,%)+ROC(C,25,%);
Buy:=Cross(MyROC,4);
Sell:=Cross(4,MyROC);

init:=Cum(IsDefined(Buy+Sell))=1;
Season:=ValueWhen(1,Buy-Sell<>0 OR init,Buy)*2-1;
Signal:=If(Season<>Ref(Season,-1),Season,0);

Signal; {1=Buy -1=Sell}

>>Where should i put the last 4 rules?
I only see two -- The ROC formula and the "Buy if closing up from yesterday". If you list the others, I can put them in.


>>In the buy and sell section?
Yes -- the BUY signal must be set with any/all conditions.


>>And maybe you can explain a little bit about their meaning.
OK, lesson time!<g> I've added comments and some flexible inputs to the indicator; let me know if it's too complex, and I'll simplify it:


_Test
{ Flexible Inputs }
Display:=Input("Display 0=Indicator 1=Signal 2=Season",0,2,1);
Level:=Input("Level",-10,10,4);
Pd1:=Input("Short",1,100,5);
Pd2:=Input("Medium",1,100,15);
Pd3:=Input("Long",1,100,25);

{ Criteria }
MyROC:=ROC(C,Pd1,%)+ROC(C,Pd2,%)+ROC(C,Pd3,%);

{ Conditions }
Buy:=Cross(MyROC,4) and C>ref(C,-1);
Sell:=Cross(Level,MyROC);

{ GENERIC: Filter repeat signals, 1=Buy, -1=Sell }
init:=Cum(IsDefined(Buy+Sell))=1;
Season:=ValueWhen(1,Buy-Sell<>0 OR init,Buy)*2-1;
Signal:=If(Season<>Ref(Season,-1),Season,0);

{ Display }
If(Display=1,Signal,If(Display=2,Season,MyROC));


Now, from the above Indicator, here is what you can do by creating and ATTACHing an Expert Advisor:


*************
EXPERT TABS
*************
TRENDS -- Use RIBBON button to set color. I set "Pattern" to (None).
------------
Bullish: FmlVar("_Test","Season")=1; { Ribbon=Green }
Bearish: FmlVar("_Test","Season")=-1; { Ribbon=Red }
Neutral: { Ribbon=Yellow }

HIGHLIGHTS
-------------------
Buy: FmlVar("_Test","Season")=1;
Sell: FmlVar("_Test","Season")=-1;
Default: 1

SYMBOLS -- Select symbol and color from the "Graphic" tab.
---------------
Buy: FmlVar("_Test","Signal")=1;
Sell: FmlVar("_Test","Signal")=-1;

You must have changed the name of the Indicator...

In the examples, the name of the Indicator is "_Test" (without the quotes).

Whenever an indicator or the variables within it are called from elsewhere -- another Indicator, Expert, Exploration or System Test -- you use either the FML() or FMLVAR() functions (see docs).

FmlVar("_Test","Signal")=1;

In this case, "_Test" is the name of the indicator, and "Signal" is the variable.

You're free to change "_Test" to anything you want, but then you must change the examples to be consistent.

1. It's fine to put the whole formula in the tabs, but you need to change to last lines in the tabs to:

BUY tab: Signal=1; {Positive one}
SELL tab: Signal=-1; {Negative one}


2. "Signal markers will not be drawn because the base security is not visible"

You must have deleted it from the chart. Open the chart, right-click on a blank area and left-click on "Display Base Security".

Then you should be able to plot the results. You don't need to re-run the System Test.

The System Tester gave me these results:

$COMP
2000: -3.0%
2001: +9.5%
2002: -32.1%
2003: +13.0%


>>I was wondering if you do get these results and the error lies in my settings...?
That's the most likely; re-read and see if you got the formula right, whether he's using a stop-loss, that there is no other criteria mentioned in the comments, etc.


>>From taking a closer look on a presented graph in this same book
You don't always see what you think you do; number measurements are far better.

Adding the "Positive" condition means the CROSS() needs to be changed to a ">" sign, since the MyROC combo may not happen at the exact time all three ROC's go positive.

You should be able to just "Copy& Paste" this, and the Expert & whatnot will stay the same, IF you used the FMLVAR() to call Indicator variables:

{ Criteria }
MyROC:=ROC(C,5,%)+ROC(C,15,%)+ROC(C,25,%);
Positive:=ROC(C,5,%)>0
AND ROC(C,15,%)>0
AND ROC(C,25,%)>0;

{ Conditions }
Buy:=MyROC>4 AND C>Ref(C,-1) and Positive;
Sell:=Cross(4,MyROC);

{ Filter repeat signals, 1=Buy -1=Sell }
init:=Cum(IsDefined(Buy+Sell))=1;
Season:=ValueWhen(1,Buy-Sell<>0 OR init,Buy)*2-1;
Signal:=If(Season<>Ref(Season,-1),Season,0);

{ Plot, manually add Horizontal Lines at +4 and -4 }
MyROC;

>>Signal; 1

At the end, if that's not a typo, it should be

BUY: Signal=1;
SELL: Signal=-1;

The System Tester did not give me very good results.

>>Question: is there a way to do system tests that are based on minute to minute prices?

I don't know, as I only work with EOD data.

Something else may be amiss; I've not read the book, but the system seems simple and straightforward -- if it required anything fancy, I think it would have been made plain in the text.

If you are sure you haven't misunderstood it, there are two things you could try:

1. Since you are testing the COMP, try the same test in Excel.

2. Write a letter/email to Appel, tell him you are not getting the same results as his book, and ask "Why?". Odds are, you're not the only one, so he may have a ready answer.