Hi RC

Unfortunately the unused entry signals are are not filtered out unless passed through the PREV latch so you could see a string of entry signals before an exit (as you have already pointed out). I don't usually recommend using PREV code in an expert as it makes charts open more slowly if the expert is attached to the default template. This is particularly so when large amounts of data are loaded. It's not so much of a problem if only 1 to 2 years of data are opened with each chart. For this system you don't have a lot of choice about using the PREV code because you'll find it's impossible to synchronise Buy and Sell signals otherwise. The simple latch that John suggests is fine for tracking a trades progress when the entry and exit are indepedent of each other. However, when the exit is related to some aspect of the entry the use of PREV is essential. Without it the decision-making process quickly gets out of whack.

Of course there are also situations where the use of PREV is quite unnecessary - the Darvas Box code in MS11 is a case in point.

Assuming you want your expert to display only the valid entries and exits I would organise the existing code a little differently. The PREV latch needs to be in the Buy window, and what you then do is monitor for the leading edge of Trade going true (a delay is added by the second BuyLong definition). I'd also suggest that the PREV latch NOT be included in the Sell window. The reason for this is that you'd double the number of PREVs in the expert and have more speed issues. What you can do is write the Trade latch variable to a global variable (using the GV DLL), and then call the Trade from the DLL rather than replicating all that ugly PREV code.

{Enter Long}
BuyLong:=Cross(C,Mov(C,10,S));
BuyLong:=Ref(BuyLong,-1);
SellLong:=Cross(Mov(C,100,S),Mov(C,25,S));
ATRange:=Ref(ATR(14),-0) * 1.5;
Trade:=If(PREV<=0,If(BuyLong,OPEN,0),
If(SellLong OR C>PREV+ATRange OR C<PREV-ATRange,
-PREV,PREV));
Trade:=ExtFml("GV.SetVar","LongTrade",Trade);
Trade>0 AND Alert(Trade<=0,2);

{Exit Long}
Trade:=ExtFml("GV.GetVar","LongTrade");
Ref(Trade<0,-1);

Use the "Trade" global variable to derive any other alerts (or whatever) you reqire for the expert so that the PREV count is kept to five. You might wonder why the latch uses -PREV to signal an exit rather than, say, -1. Well, my tests show that -1 actually slows execution speed rather than speeding it up. Go figure. The GV DLL is available from the bottom of the page at http://www.metastocktips.co.nz/te_formulas.html.

Roy

Hi RC

Interesting that you mention a "fixed stop profit" 30.48. If you look at the code I provided you can see that the ATR value is not fixed at the entry point but floats during the trade and at the time the exit is signalled PREV+ATRange actually drops below C.

The code needs to be changed to correct that problem, but understand that it's your problem, not mine. Figuring out why things don't work the way they should is an excellent way to learn more about MetaStock so I'd encourage you to attempt your own troubleshooting.

Here's one way the previous entry code can be change to "lock in" the ATR value at the time of the entry signal. Just using ValueWhen() to remember the ATR value prior to the latch would allow the value to be changed should a secondary entry signal be received. To get around that the initial ATR value has to be available within the PREV latch for the duration of the trade. We can do that by using ValueWhen(1,PREV<=O,OPEN+ATRange) .

{Enter Long}
BuyLong:=Cross(C,Mov(C,10,S));
BuyLong:=Ref(BuyLong,-1);
SellLong:=Cross(Mov(C,100,S),Mov(C,25,S));
ATRange:=Ref(ATR(14),-0)*1.5;
Trade:=If(PREV<=0,If(BuyLong,OPEN,0),
If(SellLong OR
C>ValueWhen(1,PREV<=0,OPEN+ATRange) OR
C<ValueWhen(1,PREV<=0,OPEN-ATRange),
-PREV,PREV));
Trade:=ExtFml("GV.SetVar","LongTrade",Trade);
Trade>0 AND Alert(Trade<=0,2);

Unfortunately this structure is a little more demanding of resources than the previous version. I no longer use PREV with ValueWhen() if i can help it, but sometimes there is no better way. Somewhere in the distant past I figured out a way to merge the two PREV exit lines down to just one PREV expression but I haven't been able to get it quite right today. No matter, this "fixes" the problem you brought to my attention. From now on it's over to you to figure out what the wrinkles are and how to remove or get around them. Good luck.

Roy