In Traders Tips of November 2007 the MS code for the Short-Term Volume And Price Oscillator by Sylvain Vervoort is in the article and not shown in Traders Tips.

Can anyone provide this code in this forum.

It seems that nobody cares to publish MS code for new indicators in traditional sites like http://trader.online.pl/MSZ/!-zmiany.html (last MS update on 05/03/2007) not to mention https://www.metastock.com/Customer/Resources/TASC/ which was last updated in June 2006.
Thanks.

Herewith the code:

Greetings,
S. Vervoort

{calculate the heikin ashi closing average haCl and get the input variables}

haO:=(Ref((O+H+L+C)/4,-1) + PREV)/2;

haCl:=((O+H+L+C)/4+haO+Max((O+H+L+C)/4,Max(H,haO))+Min((O+H+L+C)/4,Min(L,haO)))/4;

period:= Input("SVAPO period :", 2, 20, 8);

cutoff:= Input("Minimum %o price change :",0,10,1);

{Inputs for standard deviation bands}

devH:= Input("Standard Deviation High :", 0.1, 5, 1.5);

devL:= Input("Standard Deviation Low :", 0.1, 5, 1.3);

stdevper:= Input("Standard Deviation Period :", 1, 200, 100);

{Smooth HaCl closing price}

haC:=Tema(haCl,period/1.6);

{Medium term MA of Volume to limit extremes and division factor}

vave:=Ref(Mov(V,period*5,S),-1);

vmax:=vave*2;

vc:=If(V<vmax,V,vmax);

{Basic volume trend}

vtr:=Tema(LinRegSlope(V,period),period);

{SVAPO result of price and volume}

SVAPO:=Tema(Sum(If(haC>(Ref(haC,-1)*(1+cutoff/1000)) AND Alert(vtr>=Ref(vtr,-1),2), vc, If(haC<(Ref(haC,-1)*(1-cutoff/1000)) AND Alert(vtr>Ref(vtr,-1),2),-vc,0)),period)/(vave+1),period);

devH*Stdev(SVAPO,stdevper);

-devL*Stdev(SVAPO,stdevper);

zeroref:=0;

zeroref;

SVAPO

In TASC's Novmber Traders'Tips it is stated that a second article is coming describing possible applications. Thanks to the author for his attention.

Regards.