Take a security, whose you plot the latest 100 bars.
Then you plot a 20 days moving average and a 14 days RSI.
Well, it would be interesting to add a "show plotting since" function, in order to show on the chart just a fraction of various indicatos chosen.
Sometimes plotting different MAs and indicators could add some troubles and confusion; so it would be great to show 14-d RSI and 25-d MA for the latest 50 bars only, if requested by the user.

This "Display plot restriction" indicator is a code example for restricting output to a specific date range:

[code:1:c429ee2f50]
{Restricts plot display to selected date period.

©Copyright 2005~2006 Jose Silva.
The grant of this license is for personal use
only - no resale or repackaging allowed.
http://www.metastocktools.com }

{ Sample plot to restrict }
plot:=RSI(14);

{ Restrict date inputs }
StDay:=Input("start Day",1,31,1);
StMnth:=Input("start Month",1,12,1);
StYear:=Input("start Year",1800,2200,2006);

EnDay:=Input("end Day",1,31,31);
EnMnth:=Input("end Month",1,12,3);
EnYear:=Input("end Year",1800,2200,2006);

{ Selected date period }
start:=Year()>StYear
OR (Year()=StYear AND (Month()>StMnth
OR Month()=StMnth AND DayOfMonth()>=StDay));
end:=Year()<EnYear
OR (Year()=EnYear AND (Month()<EnMnth
OR Month()=EnMnth AND DayOfMonth()<=EnDay));
period:=start
AND (end OR (start AND Alert(start=0,2)));

{ Start/End signals }
start:=start AND Alert(start=0,2);
end:=PeakBars(1,period OR Cum(1)=2,1)=0;

{ Restrict plot to selected date }
pds:=LastValue(BarsSince(end));
restricted:=
Ref(Ref(plot,-pds),pds)*ValueWhen(1,start,1);

{ Plot in own window }
restricted

[/code:1:c429ee2f50]


jose '-)

A small bug? C'mon... that's a feature! ;)


[code:1:f3511cfc71]
========================
Display plot restriction
========================
---8<-------------------------------------

{ Display plot restriction v2.0
Restricts plot display to selected dates.

©Copyright 2005~2006 Jose Silva.
The grant of this license is for personal use
only - no resale or repackaging allowed.
http://www.metastocktools.com }

{ Sample plot to restrict }
plot:=Mov(C,5,E);

{ Restrict date inputs }
StDay:=Input("start Day",1,31,1);
StMnth:=Input("start Month",1,12,1);
StYear:=Input("start Year",1800,2200,2006);
EnDay:=Input("end Day",1,31,31);
EnMnth:=Input("end Month",1,12,3);
EnYear:=Input("end Year",1800,2200,2006);

{ Selected date periods }
start:=Year()>StYear
OR (Year()=StYear AND (Month()>StMnth
OR Month()=StMnth AND DayOfMonth()>=StDay));
end:=Year()<EnYear
OR (Year()=EnYear AND (Month()<EnMnth
OR Month()=EnMnth AND DayOfMonth()<=EnDay));

{ Date signals }
date1:=start AND Alert(start=0,2);
date2:=end=0 AND Alert(end,2);
date2:=Zig(end AND Cum(1)>1,1,$)=1;

{ Restrict out of range date signals to chart }
start:=
If(LastValue(Cum(date1))>0,date1,Cum(1)=1);
end:=If(LastValue(Cum(date2))>0,date2,
LastValue(Cum(1))=Cum(1));

{ Restrict plot to selected date period }
pds:=LastValue(BarsSince(end));
restricted:=
Ref(Ref(plot,-pds),pds)*ValueWhen(1,start,1);

{ Plot in own window }
restricted

---8<-------------------------------------

[/code:1:f3511cfc71]


jose '-)