Rank: Advanced Member
Groups: Registered, Registered Users
Joined: 1/19/2005(UTC)
Posts: 1,065
Location: Koh Pha-Ngan, Earth
Was thanked: 2 time(s) in 2 post(s)
|
Try this MS indicator:
[code:1:05c24596a5]
======================
Candle wicks - largest
======================
---8<------------------------
{ Plots largest candle wick signals & values.
http://www.metastocktools.com }
{ User inputs }
pds:=Input("Lookback periods",1,2600,15);
wick:=Input("plot: [1]Upper, [2]Lower, [3]Upper-Lower",1,3,3);
plot:=Input("plot: [1]Signal, [2]Value, [3]Signal+Value",1,3,3);
pts:=Input("[1]$-points, [2]%-percentage of Close",1,2,1);
{ Upper Candle wick }
UpperCandleWick:=H-Max(O,C);
UpperValue:=HHV(UpperCandleWick,pds);
UpperSignal:=UpperCandleWick=UpperValue;
UpperValue:=
If(pts=1,UpperValue,UpperValue/C*100);
Upper:=If(plot=1,UpperSignal,
If(plot=2,UpperValue,UpperSignal*UpperValue));
{ Lower Candle wick }
LowerCandleWick:=Min(O,C)-L;
LowerValue:=HHV(LowerCandleWick,pds);
LowerSignal:=LowerCandleWick=LowerValue;
LowerValue:=
If(pts=1,LowerValue,LowerValue/C*100);
Lower:=If(plot=1,LowerSignal,
If(plot=2,LowerValue,LowerSignal*LowerValue));
{ Plot signals in own window }
If(wick=2,Lower,Upper);
If(wick=1,Upper,If(wick=2,Lower,-Lower))
---8<------------------------
[/code:1:05c24596a5]
jose '-)
|
